#!/usr/local/bin/perl -w
# ========================================================================
# fat2html - generate HTML from weight and body fat measurements
# Andrew Ho (andrew@tellme.com)
#
# This program generates an HTML table from an XML file provided as an
# argument filename, or piped to stdin. It uses FatXML::Parser to do the
# parsing; see the documentation for FatXML.pm for the details to the XML
# format accepted.
# ========================================================================

require 5.005;
use strict;

use FatXML ();
use Time::Local qw(timelocal);
use File::Basename qw(basename);
use Date::Calc qw(Add_Delta_Days);

use vars qw($ME);
$ME = basename $0;


# ------------------------------------------------------------------------
# Initialization

# Parse the XML input to get a FatXML::Measures object.

my $parser = FatXML::Parser->new;
my $measures = undef;

$@ = '';
eval {
    $measures = @ARGV ? $parser->parsefile(shift)
                      : $parser->parse(\*STDIN);
};

if($@ || !defined $measures) {
    if($@) {
        $@ =~ s/^\s+//gsm;
        $@ =~ s/\s+$//gsm;
        print STDERR $ME, ': parse error: ', $@, "\n";
        exit 2;
    } else {
        print STDERR $ME, ": general parse error\n";
        exit 2;
    }
}


# Pull out interesting bits of information.

my $max_weight = $measures->max_weight;
my $min_weight = $measures->min_weight;
my $max_fat = $measures->max_fat;
my $min_fat = $measures->min_fat;
my @dates = $measures->dates;


# Find the first Sunday before or on the first date to start with,
# so all our tables cover full weeks.

my $begin_date = @dates ? $dates[0] : today();
   $begin_date = date_yesterday($begin_date)
       while date_weekday($begin_date) > 0;
my $end_date = @dates ? $dates[$#dates] : today();
my $date = $begin_date;


# ------------------------------------------------------------------------
# Print HTML output

print << 'EndHTML';
<!--#include virtual="/cgi-bin/andrew/header/Personal/Fat/Weight+and+Fat"-->

<table cellpadding="0" cellspacing="0" border="0">
 <tr>
  <td align="center" style="text-align: center"><img
   src="fat.png" align="middle" border="0"
   width="640" height="360" hspace="0" vspace="0"
   alt="" /><br clear="all" /><br /></td>
 </tr><tr>
  <td align="center" style="text-align: center"><table
   cellpadding="0" cellspacing="0" border="0"><tr><td>

<table cellpadding="2" cellspacing="0" border="1">
 <tr valign="top">
  <th align="left">Date</th>
  <th align="right" class="right">Weight (lb)</th>
  <th align="right" class="right">Fat (%)</th>
EndHTML


# Loop through dates and pull measurements from them, or display
# a blank entry for that day.

my @weekday_weights = ();
my @weekday_fats = ();
my @all_weights = ();
my @all_fats = ();
my @weights = ();
my @fats = ();
while($date le $end_date) {
    my $measure = $measures->date($date);
    my $weight = undef;
    my $fat = undef;

    my $weekday = date_weekday($date);
    if($measure) {
        $weight = $measure->weight;
        $fat = $measure->fat;

        push @all_weights, $weight;
        push @all_fats, $fat;

        push @weights, $weight;
        push @fats, $fat;

        if(defined $weekday_weights[$weekday]) {
            push @{$weekday_weights[$weekday]}, $weight;
        } else {
            $weekday_weights[$weekday] = [ $weight ];
        }
        if(defined $weekday_fats[$weekday]) {
            push @{$weekday_fats[$weekday]}, $fat;
        } else {
            $weekday_fats[$weekday] = [ $fat ];
        }

        if($weight <= $min_weight) {
            $weight = sprintf '<font color="green">%0.1f</font>', $weight;
        } elsif($weight >= $max_weight) {
            $weight = sprintf '<font color="red">%0.1f</font>', $weight;
        } else {
            $weight = sprintf '%0.1f', $weight;
        }

        if($fat <= $min_fat) {
            $fat = sprintf '<font color="green">%0.1f</font>', $fat;
        } elsif($fat >= $max_fat) {
            $fat = sprintf '<font color="red">%0.1f</font>', $fat;
        } else {
            $fat = sprintf '%0.1f', $fat;
        }
    } else {
        $weight = $fat = '&nbsp;'
    }

    printf(<< '    EndHTML', $date, $weight, $fat);
 </tr><tr valign="top">
  <td align="left">%s</td>
  <td align="right" class="right">%s</td>
  <td align="right" class="right">%s</td>
    EndHTML

    my $tomorrow = date_tomorrow($date);
    if($weekday == 6) {
        printf(<< '        EndHTML', mean(\@weights), mean(\@fats));
 </tr><tr valign="top">
  <th align="left">Mean</th>
  <th align="right" class="right">%0.1f</th>
  <th align="right" class="right">%0.1f</th>
 </tr>
</table>
<br clear="all" />

        EndHTML

        @weights = ();
        @fats = ();

        if($tomorrow le $end_date) {
            print << '            EndHTML';
<table cellpadding="2" cellspacing="0" border="1">
 <tr valign="top">
  <th align="left">Date</th>
  <th align="right" class="right">Weight (lb)</th>
  <th align="right" class="right">Fat (%)</th>
            EndHTML
        }
    }

    $date = $tomorrow;
}

# Add code to not print table end if we just printed it
unless(date_weekday($date) == 0) {
    print << '    EndHTML';
 </tr>
</table>
<br clear="all" />

    EndHTML
}

print << 'EndHTML';
  </td><td>&nbsp;&nbsp;&nbsp;&nbsp;</td><td>

EndHTML

my $delta_weight = sprintf '%0.1f', 0.0 + sprintf '%0.1f',
    $measures->date($dates[$#dates])->ewma_weight -
    $measures->date($dates[0])->ewma_weight ;
my $delta_fat = sprintf '%0.1f', 0.0 + sprintf '%0.1f',
    $measures->date($dates[$#dates])->ewma_fat -
    $measures->date($dates[0])->ewma_fat ;

my $ewma_weight = sprintf '%0.1f',
    $measures->date($dates[$#dates])->ewma_weight ;
my $ewma_fat    = sprintf '%0.1f',
    $measures->date($dates[$#dates])->ewma_fat ;

my $mean_weight = sprintf '%0.1f', $measures->mean_weight;
my $mean_fat    = sprintf '%0.1f', $measures->mean_fat;

my $weight_spread = sprintf '%0.1f',
    abs($measures->max_weight - $measures->min_weight);
my $fat_spread    = sprintf '%0.1f',
    abs($measures->max_fat    - $measures->min_fat);

my $stddev_weight = sprintf '%0.1f', $measures->stddev_weight;
my $stddev_fat    = sprintf '%0.1f', $measures->stddev_fat;

print << "EndHTML";
<table cellpadding="2" cellspacing="0" border="1">
 <tr valign="top">
  <th style="background-color: black; color: white" bgcolor="#000000"
   colspan="3"><font color="#ffffff">Statistics</font></th>
 </tr><tr valign="top">
  <th align="left">Measurement</th>
  <th align="right" class="right">Weight (lb)</th>
  <th align="right" class="right">Fat (%)</th>
 </tr><tr valign="top">
  <td>Weighted Delta</td>
  <td align="right" class="right">$delta_weight</td>
  <td align="right" class="right">$delta_fat</td>
 </tr><tr valign="top">
  <td>Weighted Average</td>
  <td align="right" class="right">$ewma_weight</td>
  <td align="right" class="right">$ewma_fat</td>
 </tr><tr valign="top">
  <td>Mean</td>
  <td align="right" class="right">$mean_weight</td>
  <td align="right" class="right">$mean_fat</td>
 </tr><tr valign="top">
  <td>Minimum</td>
  <td align="right" class="right"><font color="green">$min_weight</font></td>
  <td align="right" class="right"><font color="green">$min_fat</font></td>
 </tr><tr valign="top">
  <td>Maximum</td>
  <td align="right" class="right"><font color="red">$max_weight</font></td>
  <td align="right" class="right"><font color="red">$max_fat</font></td>
 </tr><tr valign="top">
  <td>Spread</td>
  <td align="right" class="right">$weight_spread</td>
  <td align="right" class="right">$fat_spread</td>
 </tr><tr valign="top">
  <td>Standard Deviation</td>
  <td align="right" class="right">$stddev_weight</td>
  <td align="right" class="right">$stddev_fat</td>
 </tr>
</table>
<br clear="all" />

<table cellpadding="2" cellspacing="0" border="1">
 <tr valign="top">
  <th style="background-color: black; color: white" bgcolor="#000000"
   colspan="3"><font color="#ffffff">Weekday Means</font></th>
 </tr><tr valign="top">
  <th align="left">Weekday</th>
  <th align="right" class="right">Weight (lb)</th>
  <th align="right" class="right">Fat (%)</th>
EndHTML

foreach(0 .. $#weekday_weights) {
    my $weekday = ( qw( Sunday Monday Tuesday Wednesday
                        Thursday Friday Saturday) )[$_];
    my $weight = mean($weekday_weights[$_]);
    my $fat    = mean($weekday_fats[$_]);

    $weight = sprintf '%0.1f', $weight;
    $fat    = sprintf '%0.1f', $fat;

    printf(<< '    EndHTML', $weekday, $weight, $fat);
 </tr><tr valign="top">
  <td align="left">%s</td>
  <td align="right" class="right">%s</td>
  <td align="right" class="right">%s</td>
    EndHTML
}

print << 'EndHTML';
 </tr><tr valign="top">
  <td colspan="3" align="center" style="text-align: center"><img
   src="wdayhist.png" align="middle" border="0"
   width="320" height="184" hspace="0" vspace="0"
   alt="" /></td>
 </tr>
</table>
<br clear="all" />

<table cellpadding="2" cellspacing="0" border="1">
 <tr valign="top">
  <th style="background-color: black; color: white" bgcolor="#000000"><font
   color="#ffffff">Source Code</font></th>
 </tr><tr valign="top">
  <td><table cellpadding="0" cellspacing="0" border="0">
   <tr>
    <td><a href="fat.xml">fat.xml</a></td>
    <td rowspan="7">&nbsp;&nbsp;</td>
    <td>XML data file</td>
   </tr><tr>
    <td><a href="FatXML.pm">FatXML.pm</a></td>
    <td>XML parser</td
   </tr><tr>
    <td><a href="fat2html">fat2html</a></td>
    <td>Generates this HTML file</td>
   </tr><tr>
    <td><a href="fat2graph">fat2graph</a></td>
    <td>Charts trends for graph</td>
   </tr><tr>
    <td><a href="fat2wdayhist">fat2wdayhist</a></td>
    <td>Weekday histogram graphic</td>
   </tr><tr>
    <td><a href="Makefile">Makefile</a></td>
    <td>Automates this process</td>
   </tr><tr>
    <td><a href="fat.tar.gz">fat.tar.gz</a></td>
    <td>Source distribution tarball</td>
   </tr>
  </table></td>
 </tr>
</table>

  </td></tr></table></td>
 </tr>
</table>

EndHTML

print << 'EndHTML';
<!--#include virtual="/andrew/footer.html"-->
EndHTML

exit 0;


# ------------------------------------------------------------------------
# Internal subroutines

# date_weekday($date) takes $date in ISO 8601 like format (four-digit
# year, two-digit month, two-digit day, separated by hyphens) and returns
# the weekday number (as in $wday returned by localtime() the range is
# 0-6, where 0 is Sunday) corresponding to that date.

sub date_weekday {
    my $date = shift;
    my($year, $month, $day) = split '-', $date, 3;
    return unless $year && $month && $day;
    my $time = timelocal(0, 0, 0, $day, $month - 1, $year - 1900);
    my $wday = (localtime($time))[6];
    return $wday;
}


# delta_days($delta, $date) takes a delta (number of days) and an ISO 8601
# like date and returns the ISO 8601 like date shifted by $delta days.

sub delta_days {
    my $delta = shift;
    my $date = shift;
    my($year, $month, $day) = split '-', $date, 3;
    return unless $year && $month && $day;
    my($new_year, $new_month, $new_day) =
        Add_Delta_Days($year, $month, $day, $delta);
    return sprintf '%04d-%02d-%02d', $new_year, $new_month, $new_day;
}


# date_yesterday($date) and date_tomorrow($date) are calculate the dates
# one day before and after $date, respectively.

sub date_yesterday { delta_days(-1, @_) }
sub date_tomorrow  { delta_days(+1, @_) }


# today() returns today's date in ISO 8601 like format.

sub today {
    my($day, $month, $year) = (localtime time)[3,4,5];
    return sprintf '%04d-%02d-%02d', $year + 1900, $month + 1, $day;
}


# mean(@array) or mean($arrayref) returns the mean (average) of all the
# elements in @array (or $arrayref).

sub mean {
    return unless @_ > 0;
    my $values = @_ == 1 ? shift : [ @_ ];
    my $total = 0;
       $total += $_ foreach @$values;
    return $total / @$values;
}


# ========================================================================
__END__